linux-kernel - [PATCH 4/4] x86, putuser: switch 64-bit version to normal calling convention

lists.openwall.net		lists / announce owl-users owl-dev john-users john-dev passwdqc-users yescrypt popa3d-users / oss-security kernel-hardening musl sabotage tlsify passwords / crypt-dev xvendor / Bugtraq Full-Disclosure linux-kernel linux-netdev linux-ext4 linux-hardening linux-cve-announce PHC
Open Source and information security mailing list archives

Hash Suite for Android: free password hash cracker in your pocket

[<prev] [next>] [day] [month] [year] [list]

Date:   Sun, 17 Mar 2019 00:10:01 +0300
From:   Alexey Dobriyan <adobriyan@...il.com>
To:     tglx@...utronix.de, mingo@...hat.com, bp@...en8.de, hpa@...or.com
Cc:     x86@...nel.org, linux-kernel@...r.kernel.org, glauber@...lladb.com
Subject: [PATCH 4/4] x86, putuser: switch 64-bit version to normal calling
 convention

Use usual RDI, RSI for put_user()'s arguments.
Do everything in 4 registers, clobber RDX being the next in sequence.

Do CLAC as soon as possible.
Indent more.
Delete unnecessary macros.

This essentially undoes what Glauber did 10 years ago,
but the "this is the i386 way" is not an argument today :^)

Signed-off-by: Alexey Dobriyan <adobriyan@...il.com>
---

 arch/x86/include/asm/uaccess.h |    9 ++-
 arch/x86/lib/putuser_64.S      |  106 ++++++++++++++++-------------------------
 2 files changed, 50 insertions(+), 65 deletions(-)

--- a/arch/x86/include/asm/uaccess.h
+++ b/arch/x86/include/asm/uaccess.h
@@ -175,12 +175,17 @@ __typeof__(__builtin_choose_expr(sizeof(x) > sizeof(0UL), 0ULL, 0UL))
 	__builtin_expect(__ret_gu, 0);					\
 })
 
+#ifdef CONFIG_X86_32
 #define __put_user_x(size, x, ptr, __ret_pu)			\
 	asm volatile("call __put_user_" #size			\
 		     : "=a" (__ret_pu), ASM_CALL_CONSTRAINT	\
 		     : "0" ((typeof(*(ptr)))(x)), "c" (ptr) : "ebx")
-
-
+#else
+#define __put_user_x(size, x, ptr, __ret_pu)	\
+	asm volatile("call __put_user_" #size			\
+		     : "=a" (__ret_pu), ASM_CALL_CONSTRAINT	\
+		     : "D" ((typeof(*(ptr)))(x)), "S" (ptr) : "rdx")
+#endif
 
 #ifdef CONFIG_X86_32
 #define __put_user_goto_u64(x, addr, label)			\
--- a/arch/x86/lib/putuser_64.S
+++ b/arch/x86/lib/putuser_64.S
@@ -5,11 +5,8 @@
  * (C) Copyright 2005 Linus Torvalds
  * (C) Copyright 2005 Andi Kleen
  * (C) Copyright 2008 Glauber Costa
+ * (C) Copyright 2019 Alexey Dobriyan
  *
- * These functions have a non-standard call interface
- * to make them more efficient, especially as they
- * return an error value in addition to the "real"
- * return value.
  */
 #include <linux/linkage.h>
 #include <asm/thread_info.h>
@@ -18,86 +15,69 @@
 #include <asm/smap.h>
 #include <asm/export.h>
 
-
-/*
- * __put_user_X
- *
- * Inputs:	%eax[:%edx] contains the data
- *		%ecx contains the address
- *
- * Outputs:	%eax is error code (0 or -EFAULT)
- *
- * These functions should not modify any other registers,
- * as they get called from within inline assembly.
- */
-
-#define ENTER	mov PER_CPU_VAR(current_task), %_ASM_BX
-#define EXIT	ASM_CLAC ;	\
-		ret
-
 .text
+
 ENTRY(__put_user_1)
-	ENTER
-	cmp TASK_addr_limit(%_ASM_BX),%_ASM_CX
-	jae bad_put_user
+	mov	PER_CPU_VAR(current_task), %rdx
+	cmp	TASK_addr_limit(%rdx), %rsi
+	jae	bad_put_user
 	ASM_STAC
-1:	movb %al,(%_ASM_CX)
-	xor %eax,%eax
-	EXIT
+1:	mov	%dil, (%rsi)
+	ASM_CLAC
+	xor	%eax, %eax
+	ret
 ENDPROC(__put_user_1)
 EXPORT_SYMBOL(__put_user_1)
 
 ENTRY(__put_user_2)
-	ENTER
-	mov TASK_addr_limit(%_ASM_BX),%_ASM_BX
-	sub $1,%_ASM_BX
-	cmp %_ASM_BX,%_ASM_CX
-	jae bad_put_user
+	mov	PER_CPU_VAR(current_task), %rdx
+	mov	TASK_addr_limit(%rdx), %rdx
+	sub	$1, %rdx
+	cmp	%rdx, %rsi
+	jae	bad_put_user
 	ASM_STAC
-2:	movw %ax,(%_ASM_CX)
-	xor %eax,%eax
-	EXIT
+2:	mov	%di, (%rsi)
+	ASM_CLAC
+	xor	%eax, %eax
+	ret
 ENDPROC(__put_user_2)
 EXPORT_SYMBOL(__put_user_2)
 
 ENTRY(__put_user_4)
-	ENTER
-	mov TASK_addr_limit(%_ASM_BX),%_ASM_BX
-	sub $3,%_ASM_BX
-	cmp %_ASM_BX,%_ASM_CX
-	jae bad_put_user
+	mov	PER_CPU_VAR(current_task), %rdx
+	mov	TASK_addr_limit(%rdx), %rdx
+	sub	$3, %rdx
+	cmp	%rdx, %rsi
+	jae	bad_put_user
 	ASM_STAC
-3:	movl %eax,(%_ASM_CX)
-	xor %eax,%eax
-	EXIT
+4:	mov	%edi, (%rsi)
+	ASM_CLAC
+	xor	%eax, %eax
+	ret
 ENDPROC(__put_user_4)
 EXPORT_SYMBOL(__put_user_4)
 
 ENTRY(__put_user_8)
-	ENTER
-	mov TASK_addr_limit(%_ASM_BX),%_ASM_BX
-	sub $7,%_ASM_BX
-	cmp %_ASM_BX,%_ASM_CX
-	jae bad_put_user
+	mov	PER_CPU_VAR(current_task), %rdx
+	mov	TASK_addr_limit(%rdx), %rdx
+	sub	$7, %rdx
+	cmp	%rdx, %rsi
+	jae	bad_put_user
 	ASM_STAC
-4:	mov %_ASM_AX,(%_ASM_CX)
-#ifdef CONFIG_X86_32
-5:	movl %edx,4(%_ASM_CX)
-#endif
-	xor %eax,%eax
-	EXIT
+8:	mov	%rdi, (%rsi)
+	ASM_CLAC
+	xor	%eax, %eax
+	ret
 ENDPROC(__put_user_8)
 EXPORT_SYMBOL(__put_user_8)
 
 bad_put_user:
-	movl $-EFAULT,%eax
-	EXIT
+	ASM_CLAC
+	mov	$-EFAULT, %eax
+	ret
 END(bad_put_user)
 
-	_ASM_EXTABLE_UA(1b, bad_put_user)
-	_ASM_EXTABLE_UA(2b, bad_put_user)
-	_ASM_EXTABLE_UA(3b, bad_put_user)
-	_ASM_EXTABLE_UA(4b, bad_put_user)
-#ifdef CONFIG_X86_32
-	_ASM_EXTABLE_UA(5b, bad_put_user)
-#endif
+_ASM_EXTABLE_UA(1b, bad_put_user)
+_ASM_EXTABLE_UA(2b, bad_put_user)
+_ASM_EXTABLE_UA(4b, bad_put_user)
+_ASM_EXTABLE_UA(8b, bad_put_user)