| lists.openwall.net | lists / announce owl-users owl-dev john-users john-dev passwdqc-users yescrypt popa3d-users / oss-security kernel-hardening musl sabotage tlsify passwords / crypt-dev xvendor / Bugtraq Full-Disclosure linux-kernel linux-netdev linux-ext4 linux-hardening linux-cve-announce PHC | |
|
Open Source and information security mailing list archives
| ||
|
Message-ID: <20240108113950.360438-1-jackmanb@google.com>
Date: Mon, 8 Jan 2024 11:39:50 +0000
From: Brendan Jackman <jackmanb@...gle.com>
To: luto@...nel.org, tglx@...utronix.de, peterz@...radead.org,
dave.hansen@...ux.intel.com
Cc: mingo@...hat.com, bp@...en8.de, x86@...nel.org, hpa@...or.com,
linux-kernel@...r.kernel.org, laijs@...ux.alibaba.com, yosryahmed@...gle.com,
reijiw@...gle.com, oweisse@...gle.com, Brendan Jackman <jackmanb@...gle.com>
Subject: [PATCH v3 RESEND] x86/entry: Avoid redundant CR3 write on paranoid returns
From: Lai Jiangshan <laijs@...ux.alibaba.com>
This path gets used called from:
1. #NMI return.
2. paranoid_exit (i.e. #MCE, #VC, #DB and #DF return)
Contrary to the implication in commit 21e94459110252 ("x86/mm: Optimize
RESTORE_CR3"), the kernel never modifies CR3 in any of these exceptions,
except for switching from user to kernel pagetables under PTI. That
means that most of the time when returning from an exception that
interrupted the kernel no CR3 restore is necessary. Writing CR3 is
expensive on some machines, so this commit avoids redundant writes.
I said "most of the time" because the interrupt might have come during
kernel entry before the user->kernel CR3 switch or the during exit after
the kernel->user switch. In the former case skipping the restore might
actually be be fine, but definitely not the latter. So we do still need
to check the saved CR3 and restore it if it's a user CR3.
Note this code is ONLY used for returning _to kernel code_. So the only
times where the CR3 write is necessary are in those rather special cases
mentioned above where we are in kernel _code_ but a userspace CR3.
While changing this logic the macro is given a new name to clarify its
usage, and a comment that was describing its behaviour at the call site
is removed. We can also simplify the code around the SET_NOFLUSH_BIT
invocation as we no longer need to branch to it from above.
Signed-off-by: Lai Jiangshan <laijs@...ux.alibaba.com>
[Rewrote commit message; responded to review comments]
Signed-off-by: Brendan Jackman <jackmanb@...gle.com>
Change-Id: I6e56978c4753fb943a7897ff101f519514fa0827
---
Notes:
v1: https://lore.kernel.org/lkml/20230817121513.1382800-1-jackmanb@google.com/
v1->v2: Rewrote some comments, added a proper commit message, cleaned up
the code per tglx's suggestion.
I've kept Lai as the Author. If you prefer for the blame to
record the last person that touched it then that's also fine
though, I can credit Lai as Co-developed-by.
v2: https://lore.kernel.org/lkml/20230920150443.1789000-1-jackmanb@google.com/
v2->v3: Clarified the commit message per Dave's suggestion and renamed the
macro. I did not carry PeterZ's ack since I have made some changes.
original v3 (no responses):
https://lore.kernel.org/lkml/20231108171656.3444702-1-jackmanb@google.com/
Thanks for the reviews :)
arch/x86/entry/calling.h | 26 ++++++++++----------------
arch/x86/entry/entry_64.S | 7 +++----
2 files changed, 13 insertions(+), 20 deletions(-)
diff --git a/arch/x86/entry/calling.h b/arch/x86/entry/calling.h
index f6907627172b..25cbfba1fe46 100644
--- a/arch/x86/entry/calling.h
+++ b/arch/x86/entry/calling.h
@@ -233,17 +233,19 @@ For 32-bit we have the following conventions - kernel is built with
.Ldone_\@:
.endm
-.macro RESTORE_CR3 scratch_reg:req save_reg:req
+/* Restore CR3 from a kernel context. May restore a user CR3 value. */
+.macro PARANOID_RESTORE_CR3 scratch_reg:req save_reg:req
ALTERNATIVE "jmp .Lend_\@", "", X86_FEATURE_PTI
- ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
-
/*
- * KERNEL pages can always resume with NOFLUSH as we do
- * explicit flushes.
+ * If CR3 contained the kernel page tables at the paranoid exception
+ * entry, then there is nothing to restore as CR3 is not modified while
+ * handling the exception.
*/
bt $PTI_USER_PGTABLE_BIT, \save_reg
- jnc .Lnoflush_\@
+ jnc .Lend_\@
+
+ ALTERNATIVE "jmp .Lwrcr3_\@", "", X86_FEATURE_PCID
/*
* Check if there's a pending flush for the user ASID we're
@@ -251,20 +253,12 @@ For 32-bit we have the following conventions - kernel is built with
*/
movq \save_reg, \scratch_reg
andq $(0x7FF), \scratch_reg
- bt \scratch_reg, THIS_CPU_user_pcid_flush_mask
- jnc .Lnoflush_\@
-
btr \scratch_reg, THIS_CPU_user_pcid_flush_mask
- jmp .Lwrcr3_\@
+ jc .Lwrcr3_\@
-.Lnoflush_\@:
SET_NOFLUSH_BIT \save_reg
.Lwrcr3_\@:
- /*
- * The CR3 write could be avoided when not changing its value,
- * but would require a CR3 read *and* a scratch register.
- */
movq \save_reg, %cr3
.Lend_\@:
.endm
@@ -279,7 +273,7 @@ For 32-bit we have the following conventions - kernel is built with
.endm
.macro SAVE_AND_SWITCH_TO_KERNEL_CR3 scratch_reg:req save_reg:req
.endm
-.macro RESTORE_CR3 scratch_reg:req save_reg:req
+.macro PARANOID_RESTORE_CR3 scratch_reg:req save_reg:req
.endm
#endif
diff --git a/arch/x86/entry/entry_64.S b/arch/x86/entry/entry_64.S
index de6469dffe3a..d65182500bfe 100644
--- a/arch/x86/entry/entry_64.S
+++ b/arch/x86/entry/entry_64.S
@@ -957,14 +957,14 @@ SYM_CODE_START_LOCAL(paranoid_exit)
IBRS_EXIT save_reg=%r15
/*
- * The order of operations is important. RESTORE_CR3 requires
+ * The order of operations is important. PARANOID_RESTORE_CR3 requires
* kernel GSBASE.
*
* NB to anyone to try to optimize this code: this code does
* not execute at all for exceptions from user mode. Those
* exceptions go through error_return instead.
*/
- RESTORE_CR3 scratch_reg=%rax save_reg=%r14
+ PARANOID_RESTORE_CR3 scratch_reg=%rax save_reg=%r14
/* Handle the three GSBASE cases */
ALTERNATIVE "jmp .Lparanoid_exit_checkgs", "", X86_FEATURE_FSGSBASE
@@ -1393,8 +1393,7 @@ end_repeat_nmi:
/* Always restore stashed SPEC_CTRL value (see paranoid_entry) */
IBRS_EXIT save_reg=%r15
- /* Always restore stashed CR3 value (see paranoid_entry) */
- RESTORE_CR3 scratch_reg=%r15 save_reg=%r14
+ PARANOID_RESTORE_CR3 scratch_reg=%r15 save_reg=%r14
/*
* The above invocation of paranoid_entry stored the GSBASE
--
2.42.0.869.gea05f2083d-goog
Powered by blists - more mailing lists